#pragma rtGlobals=1		// Use modern global access method.

////////////////////////////////////////////////////////////////////////////////
// Procedure for Bowling
////////////////////////////////////////////////////////////////////////////////

////////////////////////////////////////////////////////////////////////////////
//
//	Ctrl+1	データ入力用パネルの表示
//	Ctrl+2	全員の成績を解析
//	Ctrl+3	すべてのグラフを表示
//	Ctrl+6	グラフ、テーブルの破棄
//	Ctrl+0	Procedure表示
//
////////////////////////////////////////////////////////////////////////////////

////////////////////////////////////////////////////////////////////////////////
//	使い方
//
//	０．パネルの表示
//		Ctrl+1
//	１．人の新規登録
//		Name ポップアップで"New"を選ぶ
//		ダイアログで名前を入力
//	２．データの入力
//		人・日付・何ゲーム目か・投球ごとのスコアを入力する
//		Action ポップアップで"Input"を選択してActionボタンを押す
//	３．データの表示
//		人・日付・何ゲーム目かを入力する
//		Action ポップアップで"Load"を選択してActionボタンを押す
//	４．解析
//		個人の成績を解析
//			人を選択する
//			Action ポップアップで"Analyze"を選択してActionボタンを押す
//		全員の成績を一度に解析
//			Ctrl+2
//	５．表示
//		Action ポップアップで"Display"を選択してActionボタンを押す
//		ダイアログで「表示したい成績項目」、「Graph or Table」を順に選択
//		すべての項目を表示するときは、
//			グラフ	Ctrl+3
//			表		Ctrl+4
////////////////////////////////////////////////////////////////////////////////

////////////////////////////////////////////////////////////////////////////////
//	拡張	成績項目の増やし方
//
//	１．	BowlingInitialize 内で
//			Make/O/T/N=6 Stats				
//				のデータ点数を増やす			
//			Stats[]={"Score","Avg_0","Avg_5","Strike","Spare","Mark"}
//				に名称を追加する
//	２．	その解析をおこなう関数を定義
//	３．	AnalyzeScore 内で
//			その解析をおこなう関数を追加
//			Wave Score,Avg_0,Avg_5,Strike,Spare,Mark
//			Sort Game,Game,Score,Avg_0,Avg_5,Strike,Spare,Mark
//				にそれぞれWaveを追加
//
////////////////////////////////////////////////////////////////////////////////

Menu "Bowling"
	"Panel/1",BowlingPanel()
	"Analyze All/2",AnalyzeAll()
	"Display All Graph/3",AllGraph()
	"Display All Table/4",AllTable()
	"Kill All Window/6",KillAllWindow()
	"EditProcedure/S0",DisplayProcedure "BowlingInitialize"
	BowlingInitialize()
End

Function/S BowlingInitialize()
	String folder
	folder=GetDataFolder(1)
	NewDataFolder/S/O root:Bowling
	if(WaveExists(Name)==0)
		Make/O/T/N=0 Name
	endif
	if(WaveExists(Game)==0)
		Make/O/T/N=0 Game
	endif
	Make/O/T/N=6 Stats
	Stats[]={"Score","Avg_0","Avg_5","Strike","Spare","Mark"}
	Make/T/O/N=21 Input
	String/G YearStr,DateStr,GameStr,Number
	YearStr="2006"
	DateStr="0401"
	GameStr="1"
	Number="20060401001"
	BowlingPanel()
	SetDataFolder $folder
	return ""
End

////////////////////////////////////////////////////////////////////////////////
//データ入力用パネル
////////////////////////////////////////////////////////////////////////////////

Function BowlingPanel()
	String folder,ctrlname,cmd
	Variable i,j,xpos,ypos,num
	folder=GetDataFolder(1)
	SetDataFolder root:Bowling
	Wave/T Name,Input
	SVar YearStr,DateStr,GameStr
	Input[]="0"
	Input[20]=""
	DoWindow/K Bowling
	NewPanel/W=(10,50,600,160)
	DoWindow/C Bowling
	cmd="PopupMenu NamePop value=\""
	num=DimSize(Name,0)
	if(num)
		for(i=0;i<num;i+=1)
			cmd=cmd+Name[i]+";"
		endfor
	endif
	cmd=cmd+"New;\""
	Execute cmd
	PopupMenu NamePop pos={10,10},proc=NamePopProc,title="Name"
	PopupMenu ActionPop pos={10,40},value="Load;Input;Analyze;Display;",title="Action"
	Button ActionButton pos={30,70},proc=ActionButtonProc,title="Action"
	SetVariable SetYear fsize=14,value=YearStr,pos={120,10},proc=SetDateProc,size={70,30},title="Year"
	SetVariable SetDate fsize=14,value=DateStr,pos={120,40},proc=SetDateProc,size={70,30},title="Date"
	SetVariable SetGame fsize=14,value=GameStr,pos={120,70},proc=SetDateProc,size={70,30},title="Game"
	TitleBox FirstTitle pos={200,35},size={60,20},title="1st"
	TitleBox SecondTitle pos={200,65},size={60,20},title="2nd"	 
	for(i=0;i<10;i+=1)
		xpos=240+i*30
		ctrlname="Frame"+num2str(i)+"Title"
		TitleBox $ctrlname pos={xpos,10},size={50,20},title=num2str(i+1)+"F"
		ctrlname="Set"+num2str(i)+"0"
		SetVariable $ctrlname value=Input[2*i],proc=SetPointProc,pos={xpos,40},size={30,15},title=" "
		ctrlname="Set"+num2str(i)+"1"
		SetVariable $ctrlname value=Input[2*i+1],proc=SetPointProc,pos={xpos,70},size={30,15},title=" "
	endfor
	SetVariable Set92 value=Input[20],proc=SetPointProc,pos={510,90},size={30,15},title=" "
	ResetScore()
	SetDataFolder $folder
End


Function ActionButtonProc(ctrlName) : ButtonControl
	String ctrlName
	String action
	ControlInfo ActionPop
	Execute S_Value+"Score()"
End

////////////////////////////////////////////////////////////
//  人・日付の設定
////////////////////////////////////////////////////////////

Function NamePopProc(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	Wave/T Name=root:Bowling:Name
	String folder,player,cmd
	Variable i,num
	num=DimSize(Name,0)
	folder="root:"+popStr
	if(DataFolderExists(folder))
		SetDataFolder $folder
	else
		Prompt player,"PlayerName"
		DoPrompt "NewPlayer",player
		if(V_flag)
			return 0
		endif
		InsertPoints num,1,Name
		Name[num]=player
		num+=1
		NewDataFolder/O/S $("root:"+player)
		Make/O/N=0/T Game
	endif
	cmd="PopupMenu NamePop value=\""
	if(num)
		for(i=0;i<num;i+=1)
			cmd=cmd+Name[i]+";"
		endfor
	endif
	cmd=cmd+"New;\""
	Execute cmd
	LoadScore()
End

Function SetDateProc(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	Variable yr,dt,gm
	SVar YearStr=root:Bowling:YearStr
	SVar DateStr=root:Bowling:DateStr
	SVar GameStr=root:Bowling:GameStr
	SVar Number=root:Bowling:Number
	yr=trunc(str2num(YearStr))
	dt=trunc(str2num(DateStr))
	gm=trunc(str2num(GameStr))
	if(numtype(yr+dt+gm) || yr<1000 || dt<101 || 1231<dt || gm<1 || 100<gm)
		YearStr="2006"
		DateStr="0401"
		GameStr="1"
		Number="20060401001"
		return 0
	endif
	Number=num2str(1000+gm)
	Number=YearStr+DateStr+Number[1,3]
End

////////////////////////////////////////////////////////////
//  Panelへの数値の入力
////////////////////////////////////////////////////////////

Function SetPointProc(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName
	Wave/T Input=root:Bowling:Input
	Variable fVal,tVal,pnt1,pnt2,pnt3
	String setname
	fVal=str2num(ctrlName[3])
	tVal=str2num(ctrlName[4])
	pnt1=str2num(Input[2*fVal])
	pnt2=str2num(Input[2*fVal+1])
	Input[2*fVal]=num2str(pnt1)
	Input[2*fVal+1]=num2str(pnt2)
	if(fVal==9)
		if(numtype(pnt1) || 9<pnt1)
			Input[18]="X"
			pnt1=str2num(Input[20])
			if(numtype(pnt2) || 9<pnt2)
				Input[19]="X"
				if(numtype(pnt1) || 9<pnt1)
					Input[20]="X"
				endif
			elseif(numtype(pnt1) || 9<pnt1+pnt2)
					Input[20]="/"
			endif
		elseif(numtype(pnt2) || 9<pnt1+pnt2)
			Input[19]="/"
			pnt1=str2num(Input[20])
			if(numtype(pnt1) || 9<pnt1)
				Input[20]="X"
			endif
		else
			Input[20]="NaN"
		endif
		SetVariable Set92 disable=(1-StringMatch(Input[18],"X"))*(1-StringMatch(Input[19],"/"))
	else
		if(numtype(pnt1) || 9<pnt1)
			Input[2*fVal]="X"
			Input[2*fVal+1]="NaN"
		elseif(numtype(pnt2) || 9<pnt1+pnt2)
				Input[2*fVal+1]="/"
		endif
		SetVariable $(ctrlName[0,3]+"1") disable=StringMatch(Input[2*fVal],"X")
	endif
End

////////////////////////////////////////////////////////////
//  Panel の数値のリセット
////////////////////////////////////////////////////////////

Function ResetScore()
	Wave/T Input=root:Bowling:Input
	Variable i
	Input[]="0"
	Input[20]=""	
	for(i=0;i<9;i+=1)
		Execute "SetVariable Set"+num2str(i)+"0 disable=0"
		Execute "SetVariable Set"+num2str(i)+"1 disable=0"
	endfor
	SetVariable Set92 disable=1
End

////////////////////////////////////////////////////////////
//  データの入力
////////////////////////////////////////////////////////////

Function InputScore()
	Wave/T Input=root:Bowling:Input
	Wave/T rGame=root:Bowling:Game
	SVar Number=root:Bowling:Number
	Variable i,num
	String folder,dataname
	folder=GetDataFolder(1)
	dataname="Data"+Number
	Wave/T Game=$(folder+"Game")
	num=DimSize(Game,0)
	if(WaveExists($dataname)==0)
		Make/O/N=(21) $dataname
		InsertPoints num,1,Game
		Game[num]=Number
	endif
	Wave Data=$(folder+dataname)
	for(i=0;i<DimSize(Input,0);i+=1)
		strswitch(Input[i])
			case "X":
				Data[i]=10
			break
			case "/":
				Data[i]=10-Data[i-1]
			break
			case "NaN":
				Data[i]=NaN
			break

			default :
				Data[i]=str2num(Input[i])
		endswitch
	endfor
	if(SearchStringFromWave(rGame,Number)==-1)
		num=DimSize(rGame,0)
		InsertPoints num,1,rGame
		rGame[num]=Number
	endif
	Sort rGame,rGame
	DoWindow/F Bowling
End

////////////////////////////////////////////////////////////
//  データの読み込み
////////////////////////////////////////////////////////////

Function LoadScore()
	Wave/T Input=root:Bowling:Input
	SVar Number=root:Bowling:Number
	Variable gnum,i
	String cmd,folder
	folder=GetDataFolder(1)
	Wave/Z Data=$(folder+"Data"+Number)
	if(WaveExists(Data)==0)
		ResetScore()
		return 0
	endif
	Input[]=num2str(Data[p])
	for(i=0;i<9;i+=1)
		if(Data[2*i]==10)
			Input[2*i]="X"
			Input[2*i+1]="NaN"
		elseif(Data[2*i]+Data[2*i+1]==10)
			Input[2*i+1]="/"
		endif
		Execute "SetVariable Set"+num2str(i)+"0 disable="+num2str(StringMatch(Input[2*i],"NaN"))
		Execute "SetVariable Set"+num2str(i)+"1 disable="+num2str(StringMatch(Input[2*i+1],"NaN"))
	endfor
	if(Data[18]==10)
		Input[18]="X"
		if(Data[19]==10)
			Input[19]="X"
			if(Data[20]==10)
				Input[20]="X"
			endif
		elseif(Data[19]+Data[20]==10)
			Input[20]="/"
		endif
	elseif(Data[18]+Data[19]==10)
		Input[19]="/"
		if(Data[20]==10)
			Input[20]="X"
		endif
	endif
	SetVariable Set90 disable=StringMatch(Input[18],"NaN")
	SetVariable Set91 disable=StringMatch(Input[19],"NaN")
	SetVariable Set92 disable=StringMatch(Input[20],"NaN")
End


////////////////////////////////////////////////////////////
//解析
////////////////////////////////////////////////////////////

//すべてのPlayerについて、Dataからすべての解析をおこなう
Function AnalyzeAll()
	Wave/T Name=root:Bowling:Name
	Variable i,pnum
	String path
	for(i=0;i<DimSize(Name,0);i+=1)
		path="root:"+Name[i]
		SetDataFolder $path
		AnalyzeScore()
	endfor
End

//そのPlayerについての解析をおこなう
Function AnalyzeScore()
	DataToScore()
	ScoreToAvg(0)
	ScoreToAvg(5)
	DataToMark()
	Wave/T Game
	Wave Score,Avg_0,Avg_5,Strike,Spare,Mark
	Sort Game,Game,Score,Avg_0,Avg_5,Strike,Spare,Mark
End

//DataからScoreを計算
Function DataToScore()
	if(WaveExists(Game))
		Wave/T Game
	else
		return 0
	endif
	Variable i,j,k,size
	size=DimSize(Game,0)
	Make/O/N=(size) Score
	Score[]=NaN
	for(k=0;k<size;k+=1)
		Wave Data=$("Data"+Game[k])
		if(numtype(Data[0])==0)
			Score[k]=0
			for(i=0;i<9;i+=1)
				Score[k]+=Data[2*i]
				if(Data[2*i]==10)	//strike
					Score[k]+=Data[2*i+2]
					if(numtype(Data[2*i+3])==0)
						Score[k]+=Data[2*i+3]
					else
						Score[k]+=Data[2*i+4]
					endif
				else
					Score[k]+=Data[2*i+1]
					if(Data[2*i]+Data[2*i+1]==10)	//spare
						Score[k]+=Data[2*i+2]
					endif
				endif
			endfor
			Score[k]+=Data[18]
			Score[k]+=Data[19]
			if(numtype(Data[20])==0)
				Score[k]+=Data[20]
			endif
		endif
	endfor
End

//Scoreから最近numゲーム分のAverageを計算
//結果はAvg_num
//num=0のときは全ゲームにについて計算する
Function ScoreToAvg(num)
	Variable num
	if(WaveExists(Score)==0)
		DataToScore()
	endif
	Wave Score
	Variable i,size
	size=DimSize(Score,0)
	Make/O/N=(size) $("Avg_"+num2str(num))
	Wave Avg=$("Avg_"+num2str(num))
	if(num==0)
		num=size
	endif
	for(i=0;i<size;i+=1)
		if(i<num)
			Make/O/N=(i+1) part
		else
			Make/O/N=(num) part
		endif
		part[]=Score[i-p]
		WaveStats/Q/M=1 part
		Avg[i]=V_avg
	endfor
	KillWaves part
End

//DataからStrike,Spare,Markを計算
Function DataToMark()
	if(WaveExists(Game))
		Wave/T Game
	else
		return 0
	endif
	Variable k,i,size,stnum,spnum,num1,num2
	size=DimSize(Game,0)
	num1=10
	num2=10
	Make/O/N=(size) Strike,Spare,Mark
	for(k=0;k<size;k+=1)
		Wave Data=$("Data"+Game[k])
		for(i=0;i<9;i+=1)
			if(Data[2*i]==10)	//strike
				stnum+=1
				num2-=1
			else
				if(Data[2*i]+Data[2*i+1]==10)	//spare
					spnum+=1
				endif
			endif
		endfor
		if(Data[18]==10)
			stnum+=1
			num1+=1
			if(Data[19]==10)
				stnum+=1
				num1+=1
				num2-=1
				if(Data[20]==10)
					stnum+=1
				endif
			else
				if(Data[19]+Data[20]==10)
					spnum+=1
				endif
			endif
		elseif(Data[18]+Data[19]==10)
			spnum+=1
			num1+=1
			if(Data[20]==10)
				stnum+=1
			endif
		endif
		Strike[k]=stnum/num1
		Spare[k]=spnum/num2
		Mark[k]=(stnum+spnum)/num1
	endfor
End

////////////////////////////////////////////////////////////
//表示
////////////////////////////////////////////////////////////

Function DisplayScore()
	String sname,type,cmd,list
	Variable i
	Wave/T Stats=root:Bowling:Stats
	list="All;Today;"
	for(i=0;i<DimSize(Stats,0);i+=1)
		list=list+Stats[i]+";"
	endfor
	Prompt sname,"Choose Stats",popup,list
	DoPrompt "Stats",sname
	if(V_flag)
		return 0
	endif
	if(stringmatch(sname,"Today"))
		TodayTable()
	else
		Prompt type,"Choose Type",popup,"Graph;Table;"
		DoPrompt "Type",type
		if(V_flag)
			return 0
		endif
		if(stringmatch(sname,"All"))
			cmd="All"+type+"()"
		else
			cmd="Each"+type+"(\""+sname+"\")"
		endif
		Execute cmd
	endif
End

//すべてのグラフを表示
Function AllGraph()
	Wave/T Stats=root:Bowling:Stats
	Variable i
	for(i=0;i<DimSize(Stats,0);i+=1)
		EachGraph(Stats[i])
	endfor
End

//すべての表を表示
Function AllTable()
	Wave/T Stats=root:Bowling:Stats
	Variable i
	for(i=0;i<DimSize(Stats,0);i+=1)
		EachTable(Stats[i])
	endfor
	TodayTable()
End

//ある成績についてのグラフを表示
Function EachGraph(sname)
	String sname
	Wave/T Name=root:Bowling:Name
	Wave/T AllGame=root:Bowling:Game
	Variable i,num
	String folder,date1,date2
	num=0
	folder=GetDataFolder(1)
	SetDataFolder root:Bowling
	Make/O/N=0 DatePos
	Make/O/N=0/T DateLabel
	SetDataFolder $folder
	date1=""
	for(i=0;i<DimSize(rootGame,0);i+=1)
		date2=AllGame[i]
		if(StringMatch(date1[0,7],date2[0,7])==0)
			InsertPoints num,1,DateLabel,DatePos
			DateLabel[num]=date2[0,7]
			DatePos[num]=i
			date1=date2
			num+=1
		endif
	endfor
	num=DimSize(Name,0)
	String list,LegStr
	LegStr=""
	DoWindow/K $(sname+"Graph")
	Display
	DoWindow/C $(sname+"Graph")
	ColorTab2Wave Rainbow
	Wave M_colors
	SetScale/I x,0,num,M_Colors
	for(i=0;i<num;i+=1)
		SetDataFolder $("root:"+Name[i])
		Wave/T Game
		Duplicate/O $sname,Xaxis
		Xaxis[]=SearchStringFromWave(AllGame,Game[p])
		AppendToGraph $sname vs Xaxis
	endfor
	ModifyGraph userticks(bottom)={DatePos,DateLabel},mode=4
	Label bottom "Date"
	list=TraceNameList("",";",1)
	num=ItemsInList(List)
	for(i=0;i<num;i+=1)
		ModifyGraph rgb[i]=(M_colors(i)[0],M_colors(i)[1],M_colors(i)[2]),marker[i]=i
		if(i)
			LegStr+="\r"
		endif
		LegStr+="\\s("+StringFromList(i,list)+") "+Name[i]
	endfor
	Legend/C/N=text0/J LegStr
	KillWaves M_colors
End

//ある成績についての表を表示
Function EachTable(sname)
	String sname
	String folder
	folder=GetDataFolder(1)
	SetDataFolder root:Bowling
	Wave/T AllGame=Game
	Wave/T Name
	Variable i,j,gnum,pnum,pos
	gnum=DimSize(AllGame,0)
	pnum=DimSize(Name,0)
	Make/O/N=(gnum,pnum) $(sname+"Mat")
	Wave TableMat=$(sname+"Mat")
	TableMat[][]=NaN
	SetDataFolder $folder
	DoWindow/K $(sname+"Table")
	Edit AllGame,TableMat
	DoWindow/C $(sname+"Table")
	ModifyTable title[1]="Game",width(Point)=0
	for(j=0;j<pnum;j+=1)
		SetDataFolder $("root:"+Name[j])
		Wave/T Game
		Wave StatsWave=$sname
		gnum=DimSize(Game,0)
		for(i=0;i<gnum;i+=1)
			pos=SearchStringFromWave(AllGame,Game[i])
			if(0<=pos)
				TableMat[pos][j]=StatsWave[i]
			endif
		endfor
		ModifyTable title[j+2]=Name[j]
	endfor
End

//現時点での成績についての表を表示
Function TodayTable() 
	Variable i,j,pnum,snum,gnum
	String folder
	folder=GetDataFolder(1)
	SetDataFolder root:Bowling
	Wave/T Name
	Wave/T Stats
	pnum=DimSize(Name,0)
	snum=DimSize(Stats,0)
	Make/O/N=(pnum,snum-1) TodayMat
	SetDataFolder $folder
	DoWindow/K Today
	Edit Name,TodayMat
	DoWindow/C Today
	ModifyTable width(Point)=0,title[1]="Name"
	for(j=0;j<snum-1;j+=1)
		for(i=0;i<pnum;i+=1)
			Wave input=$("root:"+Name[i]+":"+Stats[j+1])
			TodayMat[i][j]=input[DimSize(input,0)]
		endfor
		ModifyTable title[j+2]=Stats[j+1]
	endfor
End

//グラフ・テーブルの消去
Function KillAllWindow()
	String name
	Do
		name=WinName(0,3)
		if(strlen(name)==0)
			return 0
		endif
		DoWindow/K $name
	While(1)
End

//その他
Function SearchStringFromWave(wref,str)
	Wave/T/Z wref
	String str
	Variable i,num
	if(WaveExists(wref) && WaveType(wref)==0)
		for(i=0;i<DimSize(wref,0);i+=1)
			if(StringMatch(wref[i],str))
				return i
			endif
		endfor
	endif
	return -1
End