#pragma rtGlobals=1		// Use modern global access method.

////////////////////////////////////////////////////////////////////////////////
////////////////////  7700 CAD system
////////////////////////////////////////////////////////////////////////////////

Menu "CAD"
	"Panel/0",CADPanel()
	"Load/1",LoadCCCWave()
	"Procedure/SO0",DisplayProcedure "CADPanel"
	CADInitialize()
End

////////////////////////////////////////////////////////////////////////////////
//	Main Panel
////////////////////////////////////////////////////////////////////////////////
Function/S CADInitialize()
	NewDataFolder/O/S root:CAD
	NVar/Z Wsize,DX,DY
	if(NVar_Exists(Wsize)==0)
		Variable/G Wsize
		Wsize=0.6
	endif
	if(NVar_Exists(DX)==0)
		Variable/G DX
		DX=0
	endif
	if(NVar_Exists(DY)==0)
		Variable/G DY
		DY=0
	endif
	SetDataFolder root:
End
	
Function CADPanel()
	String list
	SetDataFolder root:CAD
	list=WaveList("*",";","TEXT:1")
	list=RemoveFromList("ListWave",list)
	list=RemoveFromList("SelectWave",list)
	NVar/Z Wsize,DX,DY
	
	Make/O/T/N=(ItemsInList(list)) ListWave
	Make/O/N=(ItemsInList(list)) SelectWave
	SetDataFolder root:
	ListWave[]=StringFromList(p,list)
	SelectWave[]=0
	Dowindow/K Main
  	NewPanel /W=(10,50,320,220)
	Dowindow/C Main

	ListBox Wave_List listwave=ListWave,mode=4,pos={10,10},size={150,150},selWave=SelectWave
	PopupMenu ActionPop mode=1,pos={170,10},proc=CADPopProc,title="Action ",value="Display;Edit;Rotate;Flip;Shift;Duplicate;Save;Kill;Merge;"
	PopupMenu DotPop mode=2,pos={170,40},title="Dotmap",value="20000;60000;240000;"
	PopupMenu CsizePop mode=4,pos={170,70},title="ChipSize",value="0.075;0.15;0.3;0.6;1.2;2.4;"
	PopupMenu AxisPop disable=1,pos={170,70}
	SetVariable SetDX disable=1,limits={-30000,30000,0},pos={170,70},size={100,15},title="Delta X ",value=DX
	SetVariable SetDY disable=1,limits={-30000,30000,0},pos={170,90},size={100,15},title="Delta Y ",value=DY
	SetVariable SetWsize limits={0,Inf,0},pos={170,100},size={90,15},title="WinSize",value=Wsize
	Button CADButton pos={200,130},proc=CADButtonProc,title="CAD"
End

Function CADPopProc(ctrlName,popNum,popStr) : PopupMenuControl
	String ctrlName
	Variable popNum
	String popStr
	Variable dotmap
	String list
	strswitch(popStr)
		case "Display":
			PopupMenu CsizePop disable=0
			PopupMenu DotPop disable=0
			SetVariable SetWsize disable=0
			PopupMenu AxisPop disable=1
			SetVariable SetDX disable=1
			SetVariable SetDY disable=1	
		break
		case "Rotate":
			PopupMenu CsizePop disable=1
			PopupMenu DotPop disable=0
			SetVariable SetWsize disable=1
			PopupMenu AxisPop disable=0,title="Angle   ",value="90;180;270;"
			SetVariable SetDX disable=1
			SetVariable SetDY disable=1
		break
		case "Flip":
			PopupMenu CsizePop disable=1
			PopupMenu DotPop disable=0
			SetVariable SetWsize disable=1
			PopupMenu AxisPop disable=0,title="Axis    ",value="X;Y;"
			SetVariable SetDX disable=1
			SetVariable SetDY disable=1
		break
		case "Shift":
			PopupMenu CsizePop disable=1
			PopupMenu DotPop disable=0
			SetVariable SetWsize disable=1
			PopupMenu AxisPop disable=1
			ControlInfo DotPop
			dotmap=str2num(S_Value)
			SetVariable SetDX disable=0,limits={-dotmap/2,dotmap/2,1}
			SetVariable SetDY disable=0,limits={-dotmap/2,dotmap/2,1}
		break
		default:
			PopupMenu CsizePop disable=1
			PopupMenu DotPop disable=1
			SetVariable SetWsize disable=1
			PopupMenu AxisPop disable=1
			SetVariable SetDX disable=1
			SetVariable SetDY disable=1	
	endswitch
	SetDataFolder root:CAD
	Wave/T ListWave
	Wave SelectWave
	list=WaveList("*",";","TEXT:1")
	list=RemoveFromList("ListWave",list)
	list=RemoveFromList("SelectWave",list)
	ReDimension/N=(ItemsInList(list)) ListWave
	ReDimension/N=(ItemsInList(list)) SelectWave
	ListWave[]=StringFromList(p,list)
	SelectWave[]=0
	SetDataFolder root:
End

Function CADButtonProc(ctrlName) : ButtonControl
	String ctrlName
	Variable i,num,val1,val2,j
	String list,action,name,state
	SetDataFolder root:CAD
	NVar DX,DY
	Wave/T ListWave
	Wave SelectWave
	state=KeyboardState("")
	num=DimSize(ListWave,0)
	ControlInfo DotPop
	val1=str2num(S_Value)
	ControlInfo AxisPop
	val2=V_Value
	ControlInfo ActionPop
	action=S_Value
	strswitch(action)
		case "Display": //Ctrl : Old CAD Window is duplicated. Alt : Append to Old CAD Window
			DoWindow/F CAD
			if(V_flag && StringMatch(state[0],"1"))
				DoWindow/C $("CAD_"+num2str(ItemsInList(WinList("CAD_*",";","WIN:1"))+1))
				Display/W=(10,150,350,490)
				DoWindow/C CAD
			endif
			if(V_flag==0 || StringMatch(state[1],"0"))
				DoWindow/K CAD
				Display/W=(10,150,350,490)
				DoWindow/C CAD
			endif
			for(i=0;i<num;i+=1)
				if(SelectWave[i])
					DisplayPrompt(ListWave[i])
				endif
			endfor
		break

		case "Edit":
			DoWindow/K CCCTable
			Edit/W=(350,10,750,190)
			DoWindow/C CCCTable
			for(i=0;i<num;i+=1)
				if(SelectWave[i]*WaveExists($ListWave[i]))
					AppendToTable $ListWave[i]
				endif
			endfor
			ModifyTable alignment=0,width=40,width[0]=0,width[1]=60,width[10]=20,width[11]=20,width[12]=20
		break
		
		case "Rotate":
			for(i=0;i<num;i+=1)
				name=ListWave[i]
				if(SelectWave[i]*WaveExists($name))
					for(j=0;j<val2;j+=1)
						RotateCCC(name,val1)
					endfor
				endif
			endfor
		break

		case "Flip":
			for(i=0;i<num;i+=1)
				name=ListWave[i]
				if(SelectWave[i]*WaveExists($name))
					FlipCCC(name,val1,val2)
				endif
			endfor
		break

		case "Shift":
			for(i=0;i<num;i+=1)
				name=ListWave[i]
				if(SelectWave[i]*WaveExists($name))
					ShiftCCC(name,DX,DY)
				endif
			endfor
		break

		case "Duplicate": // Alt : Oiginal CCC wave is Killed
			for(i=0;i<num;i+=1)
				if(SelectWave[i]*WaveExists($ListWave[i]))
					name=ListWave[i]+"_New"
					Prompt name,"NewName"
					DoPrompt "Duplicate",name
					if(V_flag+StringMatch(name,ListWave[i])==0)
						Duplicate/O $ListWave[i],$name
						if(StringMatch(state[1],"1"))
							KillWaves/Z $ListWave[i]
						endif
					endif
				endif
			endfor
		break

		case "Save":
			for(i=0;i<num;i+=1)
				if(SelectWave[i])
					SaveCCCwave(ListWave[i])
				endif
			endfor
		break

		case "Kill":
			for(i=0;i<num;i+=1)
				if(SelectWave[i]*WaveExists($ListWave[i]))
					KillWaves/Z $ListWave[i]
				endif
			endfor
		break

		case "Merge":
			val1=0
			for(i=0;i<num;i+=1)
				if(SelectWave[i]*WaveExists($ListWave[i]))
					if(val1)
						AppendCCC(name,ListWave[i],name)
					else
						name=ListWave[i]+"New"
						Prompt name,"NewName"
						DoPrompt "Merge",name
						if(V_flag==0)
							Duplicate/O $ListWave[i],$name
							val1=1
						endif
					endif
				endif
			endfor
		break
	endswitch
	list=WaveList("*",";","TEXT:1")
	list=RemoveFromList("ListWave",list)
	list=RemoveFromList("SelectWave",list)
	ReDimension/N=(ItemsInList(list)) ListWave
	ReDimension/N=(ItemsInList(list)) SelectWave
	ListWave[]=StringFromList(p,list)
	SelectWave[]=0
	SetDataFolder root:
End

//////////	Laod	//////////
Function LoadCCCWave()
	String S_filename,str
	Variable i,num,len,j,pnt
	S_filename=""
	LoadWave/N/J/Q/O/K=2/V={""," $",0,0}
	if(StringMatch(S_filename,""))
		return 0
	endif
	Wave/T wave0
	S_filename=S_filename[0,strlen(S_filename)-5]
	num=DimSize(wave0,0)
	SetDataFolder root:CAD:
	Make/O/T/N=(num,12) $S_filename
	Wave/T CCCwave=$("root:CAD:"+S_filename)
	CCCwave[][]=""
	for(i=0;i<num;i+=1)
		CCCwave[i][0]=StringFromList(0,wave0[i],"(")
		str=StringFromList(1,wave0[i],"(")
		CCCwave[i][11]=StringFromList(1,str,";")
		str=StringFromList(0,str,")")
		len=ItemsInList(str,",")
		CCCwave[i][10]=StringFromList(len-1,str,",")
		CCCwave[i][9]=StringFromList(len-2,str,",")
		strswitch(CCCwave[i][0])
			case "DWSL":
				pnt=4
			break

			case "DWLTL":
				CCCwave[i][9]=""
				pnt=4
			break

			case "DWTL":
				pnt=6
			break
			case "DWCL":
				pnt=3
			break
			case "DWTZL":
				pnt=8
			break
		endswitch
		for(j=0;j<pnt;j+=1)
			CCCwave[i][j+1]=StringFromList(j,str,",")
		endfor
	endfor
	KillWaves/Z wave0
End

//////////	Display	//////////

Function DisplayPrompt(name)
	String name
	if(WaveExists($("root:CAD:"+name))==0)
		return 0
	endif
	Variable size,dotmap,left,top
	NVar Wsize=root:CAD:Wsize
	ControlInfo/W=Main CsizePop
	size=str2num(S_Value)
	ControlInfo/W=Main DotPop
	dotmap=str2num(S_Value)
	left=Wsize/2
	top=Wsize/2
	Prompt size,"Chip Size"
	Prompt dotmap,"Dotmap"
	Prompt left,"Center of Chip : x (mm)"
	Prompt top,"Center of Chip : y (mm)"
	DoPrompt "Place Chip : "+name,size,dotmap,left,top
	if(V_flag==0)
		left=left*dotmap/size-dotmap/2
		top=top*dotmap/size-dotmap/2
		size=Wsize*dotmap/size
		CCCwave2Figure(name,size,left,top)
	endif
End

Function CCCwave2Figure(name,size,left,top)
	String name
	Variable size,left,top
	Variable x0,y0,x1,y1,x2,y2,x3,y3,i,num
	if(WaveExists($("root:CAD:"+name))==0)
		return 0
	endif
	DoWindow/F CAD
	SetDrawEnv fillpat=0,xcoord=rel,ycoord=rel,save
	SetDrawEnv gstart
	Wave/T CCCwave=$("root:CAD:"+name)
	num=DimSize(CCCwave,0)
	for(i=1;i<num-1;i+=1)
		x0=(left+str2num(CCCwave[i][1]))/size
		y0=(top+str2num(CCCwave[i][2]))/size
		if(StringMatch(CCCwave[i][0],"DWCL"))
			x1=str2num(CCCwave[i][3])/size
		else
			x1=(left+str2num(CCCwave[i][3]))/size
		endif
		y1=(top+str2num(CCCwave[i][4]))/size
		x2=(left+str2num(CCCwave[i][5]))/size
		y2=(top+str2num(CCCwave[i][6]))/size
		x3=(left+str2num(CCCwave[i][7]))/size
		y3=(top+str2num(CCCwave[i][8]))/size
		ColorNum2Wave(str2num(CCCwave[i][11]))
		Wave W_Color=root:CAD:W_Color
		SetDrawEnv linefgc=(W_color[0],W_Color[1],W_Color[2]),fillfgc=(W_color[0],W_Color[1],W_Color[2])
		strswitch(CCCwave[i][0])
			case "DWSL":
				DrawRect x0,y0,x1,y1
			break

			case "DWLTL":
				DrawLine x0,y0,x1,y1
			break

			case "DWTL":
				DrawPoly/ABS 0,0,1,1,{x0,y0,x1,y1,x2,y2,x0,y0}
			break
			case "DWCL":
				DrawOval x0-x1,y0-x1,x0+x1,y0+x1
			break
			case "DWTZL":
				DrawPoly/ABS 0,0,1,1,{x0,y0,x1,y1,x2,y2,x3,y3,x0,y0}
			break
		endswitch
	endfor
	SetDrawEnv gstop
	KillWaves/Z W_Color
End

Function ColorNum2Wave(num)
	Variable num
	String folder
	folder=GetDataFolder(1)
	SetDataFolder root:CAD
	Make/O/N=3 W_Color
	SetDataFolder $folder
	switch(num)
		case 1:	//Blue
			W_Color={0,0,65535}
		break
		case 2:	//Green
			W_Color={0,65535,0}
		break
		case 3:	//Cyan
			W_Color={0,65535,65535}
		break
		case 4:	//Red
			W_Color={65535,0,0}
		break
		case 5:	//Mazenda
			W_Color={65535,0,65535}
		break
		case 6:	//Brown
			W_Color={32768,0,0}
		break
		case 7:	//LightGray
		case 8:	//LightGray
			W_Color={16384,16384,16384}
		break
		case 9:	//LightBlue
		case 10:	//LightBlue
		case 11:	//LightBlue
			W_Color={16384,16384,65535}
		break
		case 12:	//LightRed
		case 13:	//LightRed
			W_Color={65535,16384,16384}
		break
		case 14:	//Yellow
			W_Color={65535,65535,0}
		break
		case 15:	//White
			W_Color={0,0,0}
		break
	endswitch
End

//////////	Rotate	//////////

Function RotateCCC(name,dotmap)
	String name
	Variable dotmap
	Variable x0,y0,i,num,j
	if(WaveExists($("root:CAD:"+name))==0)
		return 0
	endif
	Wave/T CCCwave=$("root:CAD:"+name)
	num=DimSize(CCCwave,0)-1
	for(i=1;i<num;i+=1)
		j=1
		Do
			x0=str2num(CCCwave[i][2*j-1])
			y0=str2num(CCCwave[i][2*j])
			if(numtype(x0)+numtype(y0)==0)
				CCCwave[i][2*j-1]=num2str(dotmap-y0)
				CCCwave[i][2*j]=num2str(x0)
				j+=1
			else
				j=5
			endif
		While(j<5)
	endfor
End

//////////	Flip	//////////

Function FlipCCC(name,dotmap,axis)
	String name
	Variable dotmap,axis
	Variable x0,y0,i,num,j
	if(WaveExists($("root:CAD:"+name))==0)
		return 0
	endif
	Wave/T CCCwave=$("root:CAD:"+name)
	num=DimSize(CCCwave,0)-1
	for(i=1;i<num;i+=1)
		j=1
		Do
			x0=str2num(CCCwave[i][2*j-1])
			y0=str2num(CCCwave[i][2*j])
			if(numtype(x0)+numtype(y0)==0)
				if(axis==1)
					CCCwave[i][2*j-1]=num2str(dotmap-x0)
					CCCwave[i][2*j]=num2str(y0)
				else
					CCCwave[i][2*j-1]=num2str(x0)
					CCCwave[i][2*j]=num2str(dotmap-y0)
				endif
				j+=1
			else
				j=5
			endif
		While(j<5)
	endfor
End

//////////	Shift	//////////

Function ShiftCCC(name,dx,dy)
	String name
	Variable dx,dy
	Variable x0,y0,i,num,j
	if(WaveExists($("root:CAD:"+name))==0)
		return 0
	endif
	Wave/T CCCwave=$("root:CAD:"+name)
	num=DimSize(CCCwave,0)-1
	for(i=1;i<num;i+=1)
		j=1
		Do
			x0=str2num(CCCwave[i][2*j-1])
			y0=str2num(CCCwave[i][2*j])
			if(numtype(x0)+numtype(y0)==0)
				CCCwave[i][2*j-1]=num2str(x0+dx)
				CCCwave[i][2*j]=num2str(y0+dy)
				j+=1
			else
				j=5
			endif
		While(j<5)
	endfor
End

//////////	Save	//////////

Function SaveCCCwave(name)
	String name
	Variable i,num,j,val
	Wave/T CCCwave=$("root:CAD:"+name)
	num=DimSize(CCCwave,0)
	Make/O/T/N=(num) wave0
	wave0[0]=CCCwave[0][0]
	for(i=1;i<num-1;i+=1)
		wave0[i]=CCCwave[i][0]+"("
		for(j=1;j<10;j+=1)
			val=str2num(CCCwave[i][j])
			if(numtype(val)==0)
				wave0[i]=wave0[i]+CCCwave[i][j]+","
			endif
		endfor
		wave0[i]=wave0[i]+CCCwave[i][10]+");"+CCCwave[i][11]
	endfor
	wave0[num-1]=CCCwave[num-1][0]
	Save/O/G/M="\n" wave0 as name+".ccc"
	KillWaves/Z wave0
End


//////////	Append	//////////
Function AppendCCC(name1,name2,newname)
	String name1,name2,newname
	Wave/T/Z CCC1=$("root:CAD:"+name1)
	Wave/T/Z CCC2=$("root:CAD:"+name2)
	if(WaveExists(CCC1)*WaveExists(CCC2)==0)
		return 0
	endif
	Variable num1,num2
	num1=DimSize(CCC1,0)
	num2=DimSize(CCC2,0)
	Duplicate/O CCC1,root:CAD:NewCCC
	Wave/T NewCCC=root:CAD:NewCCC
	InsertPoints num1-1,num2-2,NewCCC
	NewCCC[num1-1,num1+num2-3][]=CCC2[p-num1+2][q]
	Duplicate/O NewCCC,$("root:CAD:"+newname)
	KillWaves/Z NewCCC
End


		case "Make":
			val2=500
			val3=60
			val4=10
			Prompt val2,"Length"
			Prompt val3,"Width of Path"
			Prompt val4,"Width of Wire"
			DoPrompt "Make Cross",val2,val3,val4
			if(V_flag==0)
				MakeCross(val1,val2,val3,val4,"I",3)
			endif
		break

//Function MakeCross(dotmap,l,d,w,dose,color)
	Variable dotmap,l,d,w,color
	String dose
	String name
	name="cross"+num2str(d)
	Make/O/T/N=8 $name,wave1
	Wave/T wave0=$("root:CAD:"+name)
	wave0[]=""
	wave1[]=""
	wave0[1]=num2str(dotmap/2-4*l)+","+num2str(dotmap/2-l-2*w)+","
	wave0[1]=wave0[1]+num2str(dotmap/2-2*l)+","+num2str(dotmap/2-l)+","
	wave0[2]=num2str(dotmap/2-2*l)+","+num2str(dotmap/2-l)+","
	wave0[2]=wave0[2]+num2str(dotmap/2-l)+","+num2str(dotmap/2-d/2)+","
	wave1[2]=num2str(dotmap/2-l)+","+num2str(dotmap/2-d/2-w)+","
	wave1[2]=wave1[2]+num2str(dotmap/2-2*l)+","+num2str(dotmap/2-l-2*w)+","
	wave0[3]=num2str(dotmap/2-l)+","+num2str(dotmap/2-d/2-w)+","
	wave0[3]=wave0[3]+num2str(dotmap/2-d/2)+","+num2str(dotmap/2-d/2)+","
	wave0[4]=num2str(dotmap/2-d/2-w)+","+num2str(dotmap/2-l)+","
	wave0[4]=wave0[4]+num2str(dotmap/2-d/2)+","+num2str(dotmap/2-d/2-w)+","
	wave0[5]=num2str(dotmap/2-l)+","+num2str(dotmap/2-2*l)+","
	wave0[5]=wave0[5]+num2str(dotmap/2-d/2)+","+num2str(dotmap/2-l)+","
	wave1[5]=num2str(dotmap/2-d/2-w)+","+num2str(dotmap/2-l)+","
	wave1[5]=wave1[5]+num2str(dotmap/2-l-2*w)+","+num2str(dotmap/2-2*l)+","
	wave0[6]=num2str(dotmap/2-l-2*w)+","+num2str(dotmap/2-4*l)+","
	wave0[6]=wave0[6]+num2str(dotmap/2-l)+","+num2str(dotmap/2-2*l)+","
	
	if(w)
		wave0[1]="DWSL("+wave0[1]+"1,"+dose+");"+num2str(color)
		wave0[2]="DWTZL("+wave0[2]+wave1[2]+"1,"+dose+");"+num2str(color)
		wave0[3]="DWSL("+wave0[3]+"1,"+dose+");"+num2str(color)
		wave0[4]="DWSL("+wave0[4]+"1,"+dose+");"+num2str(color)
		wave0[5]="DWTZL("+wave0[5]+wave1[5]+"1,"+dose+");"+num2str(color)
		wave0[6]="DWSL("+wave0[6]+"1,"+dose+");"+num2str(color)
	else
		wave0[]="DWLL("+wave0[p]+dose+");"+num2str(color)
	endif
	wave0[0]="PATTERN"
	wave0[8]="END"
	Duplicate/O wave0,root:CAD:wave1
	ModifyCCC("Rotate","wave1",dotmap,0)
	AppendCCC(name,"wave1",name)
	ModifyCCC("Rotate","wave1",dotmap,0)
	AppendCCC(name,"wave1",name)
	ModifyCCC("Rotate","wave1",dotmap,0)
	AppendCCC(name,"wave1",name)
	KillWaves/Z wave1
	
End