#pragma rtGlobals=1		// Use modern global access method.

////////////////////////////////////////////////////////////////////////////////
////////////////////	温度計較正
// 読み込んだデータは
//	温度：T*****
//	抵抗：R*****
// として保存しておく
//
// 使い方
//	1. CalibrationPrompt 実行（"Calibration"メニュー --> Calibration or Ctrl+0 or 直接入力）
//	2. 温度、抵抗のデータを選ぶ
//
// その他
//	関数 Calibration 内の変数 num の値を変えればFitting の次数を変更できる
//	質問・要望・バグ報告は　さの　までお願いします
////////////////////////////////////////////////////////////////////////////////

#include <XY Pair To Waveform>

Menu "Calibration"
	"Calibration/0",CalibrationPrompt()
End

Function CalibrationPrompt()
	String Tname,Rname
	Prompt Tname,"Temp",popup,WaveList("T*",";","DIMS:1")
	Prompt Rname,"Res",popup,WaveList("R*",";","DIMS:1")
	DoPrompt "Calibration",Tname,Rname
	if(V_flag==0)
		Calibration($Tname,$Rname)
	endif
End

Function Calibration(Twave,Rwave)
	Wave Twave,Rwave
	String cmd,txt,str
	Variable i,num
	num=6	//Fitting の次数
	Display Rwave vs Twave
	ModifyGraph log=1,rgb[0]=(65535,0,0),mode[0]=3,margin(top)=50,axOffset(left)=-2
	DoUpdate
	Duplicate/O Twave,$("Fit"+NameOfWave(Twave))
	Wave LogTwave=$("Fit"+NameOfWave(Twave))
	LogTwave[]=log(Twave[p])
	Duplicate/O Rwave,$("Fit"+NameOfWave(Rwave))
	Wave LogRwave=$("Fit"+NameOfWave(Rwave))
	LogRwave[]=log(Rwave[p])
	Sort LogRwave,LogRwave,LogTwave
	XYToWave1(LogRwave,LogTwave,ReplaceString("R",NameOfWave(Rwave),"Fit"),DimSize(LogRwave,0))
	Wave FitWave=$ReplaceString("R",NameOfWave(Rwave),"Fit")
	CurveFit/Q poly num, FitWave /D=FitWave
	Wave W_coef
	sprintf str,"%f",W_coef[0]
	cmd="y="+str
	txt="\\f02y\\f00 = "+str
	for(i=1;i<num;i+=1)
		if(0<W_coef[i])
			cmd=cmd+"+"
			txt=txt+"+"
		endif
		sprintf str,"%f",W_coef[i]
		cmd=cmd+str+"*x"
		txt=txt+str+"\\f02x\\f00 "
		if(1<i)
			cmd=cmd+"**"+num2str(i)
			txt=txt+"\\S"+num2str(i)+"\\M"
		endif
	endfor
	txt=txt+"\r\\f02y\\f00 = log(\\f02T\\f00 ), \\f02x\\f00 = log(\\f02R\\f00 )"
	print "y=log("+NameOfWave(Twave)+"), x=log("+NameOfWave(Rwave)+")"
	print cmd+";"
	AppendToGraph/R/T/VERT FitWave
	GetAxis/Q bottom
	SetAxis/Z top,log(V_min),log(V_max)
	GetAxis/Q left
	SetAxis/Z right,log(V_min),log(V_max)
	ModifyGraph rgb[1]=(0,0,65535),mode[1]=2,tick=2
	Label left "\\f02R\\f00 (\\[0\\F'Symbol'W\\]0)"
	Label bottom "\\f02T\\f00 (K)"
	TextBox/C/N=text0/F=0/S=3/A=LT/X=-5/Y=-35 txt
	KillWaves/Z W_coef,LogTwave,LogRwave
End